Arduino LED-Rennen spiel, Duell der Lichtpunkte

Details: Kategorie: Arduino neue Ideen; Erstellt: 19. Oktober 2025; Zugriffe: 1078

Beim LED-Rennen treten zwei Spieler gegeneinander an. Jeder steuert einen eigenen Lichtpunkt, der über eine Reihe von LEDs läuft. Mit jedem Tastendruck rückt die LED des Spielers ein Stück weiter Richtung Ziel. Wer seine LED zuerst bis ans Ende der Reihe bringt, gewinnt das Rennen!

Spiel 11 aus der 200 Arduino Spiele Sammlung.

Die Schaltung besteht nur aus einem Arduino, zwei Tastern und einer 255 LED Matrix.

Zum testen haben ich ddie beiden Taster auf ein mini Breadbord auf den Arduino gesteckt.

Der Arduino Code für das Spiel

#include <Adafruit_NeoPixel.h>

// Hardware-Konfiguration
const int LED_PIN = 9;
const int NUM_LEDS = 300;
const int BUTTON_P1 = 2;
const int BUTTON_P2 = 3;
const int SPIEL_BEREICH = 255; // Wie weit die Spieler laufen muessen

// Farben (RGB)
const uint32_t FARBE_P1 = Adafruit_NeoPixel::Color(0, 255, 0);   // Gruen
const uint32_t FARBE_P2 = Adafruit_NeoPixel::Color(0, 0, 255);   // Blau
const uint32_t FARBE_START_P1 = Adafruit_NeoPixel::Color(0, 50, 0);
const uint32_t FARBE_START_P2 = Adafruit_NeoPixel::Color(0, 0, 50);

Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, LED_PIN, NEO_GRB + NEO_KHZ800);

// Definition eines Spielers
struct Player {
  int buttonPin;
  int aktuellePosition;
  int klickZaehler;
  uint32_t farbe;
  bool hatGewonnen;
};

Player p1 = {BUTTON_P1, 0, 0, FARBE_P1, false};
Player p2 = {BUTTON_P2, SPIEL_BEREICH, 0, FARBE_P2, false};

enum SpielStatus { LAUFT, BEENDET };
SpielStatus status = LAUFT;

void setup() {
  strip.begin();
  strip.setBrightness(10);
  pinMode(p1.buttonPin, INPUT_PULLUP);
  pinMode(p2.buttonPin, INPUT_PULLUP);
  
  spielReset();
}

void loop() {
  if (status == LAUFT) {
    aktualisiereSpieler(p1, 1);  // Spieler 1 bewegt sich vorwaerts (+1)
    aktualisiereSpieler(p2, -1); // Spieler 2 bewegt sich rueckwaerts (-1)
    
    pruefeSieg();
  } else {
    // Wenn das Spiel beendet ist: Warten auf Reset (beide Knoepfe)
    if (digitalRead(p1.buttonPin) == LOW && digitalRead(p2.buttonPin) == LOW) {
      spielReset();
    }
  }
}

// Logik für die Bewegung (ehemals Unterprogramm 1 & 2)
void aktualisiereSpieler(Player &p, int richtung) {
  if (digitalRead(p.buttonPin) == LOW) {
    p.klickZaehler++;
    
    // Alle 15 Durchlaeufe bewegt sich der Pixel (Geschwindigkeitsbremse)
    if (p.klickZaehler >= 15) {
      p.klickZaehler = 0;
      p.aktuellePosition += richtung;
      
      strip.setPixelColor(p.aktuellePosition, p.farbe);
      strip.show();
    }
  }
}

void pruefeSieg() {
  if (p1.aktuellePosition >= SPIEL_BEREICH) {
    zeigeSiegAn(FARBE_P1);
  } 
  else if (p2.aktuellePosition <= 0) {
    zeigeSiegAn(FARBE_P2);
  }
}

void zeigeSiegAn(uint32_t siegerFarbe) {
  status = BEENDET;
  for (int i = 0; i < NUM_LEDS; i++) {
    strip.setPixelColor(i, siegerFarbe);
  }
  strip.show();
  delay(1000);
}

void spielReset() {
  p1.aktuellePosition = 0;
  p1.klickZaehler = 0;
  
  p2.aktuellePosition = SPIEL_BEREICH;
  p2.klickZaehler = 0;
  
  status = LAUFT;
  
  strip.clear();
  // Startpunkte markieren
  strip.setPixelColor(p1.aktuellePosition, FARBE_START_P1);
  strip.setPixelColor(p2.aktuellePosition, FARBE_START_P2);
  strip.show();
}

Kontakt

Ronnie

schwäbischer tüftler und bastler, kraftsportler, neurodivers, 45 Jahre, 1 Frau, 5 Kinder und 1003 Ideen.

Beliebte Beiträge

Neueste Beiträge