Arduino, Farben-Reflex-Duell Spiel

Arduino Ideen

Details: Kategorie: Arduino neue Ideen; Erstellt: 17. Oktober 2025; Zugriffe: 1069

arduino Reflex Duell spiel für 2 spieler Arduino-Reflex-Duell, Wer reagiert schneller?

Beim Reflex-Duell treten zwei Spieler gegeneinander an und warten gespannt auf ein Signallicht. Sobald es aufleuchtet, heißt es blitzschnell reagieren und sofort den eigenen Buzzer drücken. Das einfache Prinzip sorgt für Nervenkitzel und Spaß: Konzentration, Spannung und Reaktionsschnelligkeit entscheiden über Sieg oder Niederlage. Durch die kurzen, intensiven Runden eignet sich das Spiel perfekt für kleine Turniere, Pausenwettkämpfe oder Teamevents. Ob als rasantes Partyspiel oder als Wettbewerb mit Punkte oder KO-System, das Reflex-Duell bringt garantiert Stimmung und fordert die Reflexe aller Teilnehmer heraus!

Spiel 8 aus der 200 Arduino Spiele Sammlung.

Ablauf des REFLEX GAME:
- beide drücken
- Im weißen TFT steht "READY"
- TFT schwarz
- Spieler warten auf roten TFT
- Beide Spieler haben gedrückt
- Speiel Ende
  - TFT hat die Farbe des Tasters, der schneller war
  - TFT zeigt die Zeit beider Spieler an
- Beide müssen zum Resett drücken
Spiel beginnt von vorne

Grün hat das Spiel gewonnen, zu sehen am grünen Hintergrund und an der Zeit in Millisekunden.

Die Verdrahtung des Arduino ist relativ einfach, wenn das Display mal angeschlossen ist, es braucht nur die beiden Taster für die Spieler.

Der Arduino Code für das Spiel

#include <Adafruit_GFX.h>
#include <Adafruit_ST7735.h>
#include <SPI.h>

// Pins für das Display
const int TFT_CS = 10;
const int TFT_RST = 8;
const int TFT_DC = 9;

// Pins für die Buttons
const int PIN_BUTTON_1 = 2;
const int PIN_BUTTON_2 = 3;

Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_RST);

// Spielzustände definieren
enum SpielStatus { WAARTEN_AUF_START, VORBEREITUNG, REAKTIONSPHASE, ERGEBNIS };
SpielStatus aktuellerStatus = WAARTEN_AUF_START;

// Variablen für die Zeitmessung
unsigned long startZeitpunkt = 0;
long reaktionsZeitSpieler1 = 0;
long reaktionsZeitSpieler2 = 0;

void setup() {
  pinMode(PIN_BUTTON_1, INPUT_PULLUP);
  pinMode(PIN_BUTTON_2, INPUT_PULLUP);

  tft.initR(INITR_BLACKTAB);
  tft.setRotation(1);
  tft.fillScreen(ST7735_BLACK);
  
  zeigeStartBildschirm();
}

void loop() {
  switch (aktuellerStatus) {
    case WAARTEN_AUF_START:
      handleStart();
      break;

    case VORBEREITUNG:
      handleVorbereitung();
      break;

    case REAKTIONSPHASE:
      handleReaktion();
      break;

    case ERGEBNIS:
      handleErgebnis();
      break;
  }
}

// --- Funktionen für die einzelnen Spielphasen ---

void zeigeStartBildschirm() {
  tft.fillScreen(ST7735_BLACK);
  tft.setTextColor(ST7735_RED);
  tft.setTextSize(3);
  tft.setCursor(30, 30);
  tft.print("PRESS");
  tft.setCursor(40, 60);
  tft.print("BOTH");
}

void handleStart() {
  // Warten, bis beide Buttons gedrückt sind
  if (digitalRead(PIN_BUTTON_1) == LOW && digitalRead(PIN_BUTTON_2) == LOW) {
    aktuellerStatus = VORBEREITUNG;
  }
}

void handleVorbereitung() {
  tft.fillScreen(ST7735_WHITE);
  tft.setTextColor(ST7735_BLACK);
  tft.setTextSize(4);
  tft.setCursor(10, 30);
  tft.print("READY?");
  
  delay(900);
  tft.fillScreen(ST7735_BLACK);
  
  // Zufällige Wartezeit zwischen 0.7 und 7 Sekunden
  delay(random(700, 7000));
  
  tft.fillScreen(ST7735_RED); // Signal zum Drücken!
  startZeitpunkt = millis();
  reaktionsZeitSpieler1 = 0;
  reaktionsZeitSpieler2 = 0;
  aktuellerStatus = REAKTIONSPHASE;
}

void handleReaktion() {
  // Zeit für Spieler 1 erfassen
  if (digitalRead(PIN_BUTTON_1) == LOW && reaktionsZeitSpieler1 == 0) {
    reaktionsZeitSpieler1 = millis() - startZeitpunkt;
  }
  
  // Zeit für Spieler 2 erfassen
  if (digitalRead(PIN_BUTTON_2) == LOW && reaktionsZeitSpieler2 == 0) {
    reaktionsZeitSpieler2 = millis() - startZeitpunkt;
  }

  // Wenn beide gedrückt haben, zum Ergebnis
  if (reaktionsZeitSpieler1 > 0 && reaktionsZeitSpieler2 > 0) {
    aktuellerStatus = ERGEBNIS;
  }
}

void handleErgebnis() {
  // Hintergrundfarbe basierend auf dem Gewinner wählen
  if (reaktionsZeitSpieler1 < reaktionsZeitSpieler2) {
    tft.fillScreen(ST7735_BLUE);
  } else {
    tft.fillScreen(ST7735_GREEN);
  }

  tft.setTextColor(ST7735_BLACK);
  tft.setTextSize(2);
  
  tft.setCursor(10, 10);
  tft.print("BLAU (P1): ");
  tft.print(reaktionsZeitSpieler1);
  tft.print("ms");

  tft.setCursor(10, 60);
  tft.print("GRUEN (P2): ");
  tft.print(reaktionsZeitSpieler2);
  tft.print("ms");

  delay(2000); // Kurz warten, bevor Neustart möglich ist
  
  // Warten auf beliebigen Tastendruck für Neustart
  if (digitalRead(PIN_BUTTON_1) == LOW || digitalRead(PIN_BUTTON_2) == LOW) {
    zeigeStartBildschirm();
    aktuellerStatus = WAARTEN_AUF_START;
    delay(500); // Entprellen
  }
}

Kontakt

Ronnie

schwäbischer tüftler und bastler, kraftsportler, neurodivers, 45 Jahre, 1 Frau, 5 Kinder und 1003 Ideen.

Arduino Ideen

Arduino, Farben-Reflex-Duell Spiel

Der Arduino Code für das Spiel

Kontakt

Ronnie

Beliebte Beiträge

Neueste Beiträge